* DISCLAIMER: The following code is provided as is and should be used at your own risk. 
* No user support is available.

* Nigel Rice, November 2006


* This program relates to the material described in Chapter 8 of the book 
* Jones, A.M., Rice, N., Bago d'Uva, T. & Balia, S. (2007)
* "Applied Health Economics", London: Routledge {ISBN: 9780415397728}  


/*******************************************/
/** Do file for Health and Wages analysis **/
/*******************************************/

clear 
capture log close 

log using "health and wages W.log", replace 

set trace off 
set more off 
set mem 400m 
program drop _all 

use "wageest.dta", clear 

/* Analysis for Women */

drop if female ~= 1

summ wage lnwage age exp jbsize SouthW London Midland NorthW NorthE Scot Wales covmem covnon jobpriv ljtrain widow divsep nvrmar kids04 white deg ocse alevel hndct hlghq1 sahex sahgd prof manag skllnm skllm jobpt 

local regvars "lnwage age agesqrd exp expsqrd jbsize covmem covnon jobpriv ljtrain widow divsep nvrmar kids04 hlghq1 sahex sahgd prof manag skllnm skllm white deg SouthW London Midland NorthW NorthE Scot Wales yr9293 yr9394 yr9495 yr9596"

local regvars_fe "lnwage agesqrd exp expsqrd jbsize covmem covnon jobpriv ljtrain widow divsep nvrmar kids04 hlghq1 sahex sahgd prof manag skllnm skllm SouthW London Midland NorthW NorthE Scot Wales yr9293 yr9394 yr9495 yr9596"

reg `regvars' 

sort pid wavenum 

xtreg `regvars' , re i(pid) 
est store raneff 

xtreg `regvars_fe' , fe i(pid) 
est store fixeff 

hausman fixeff raneff 

global depvar lnwage 
global varlist agesqrd exp expsqrd jbsize covmem covnon jobpriv ljtrain widow divsep nvrmar kids04 hlghq1 sahex sahgd prof manag skllnm skllm SouthW London Midland NorthW NorthE Scot Wales
global id pid 

do "hausman_alt.do" 

xthtaylor `regvars' , endog(hlghq1 sahex sahgd prof manag skllnm skllm deg) 
est store htest 

hausman fixeff htest 

xthtaylor `regvars' , endog(hlghq1 sahex sahgd prof manag skllnm skllm deg) amacurdy t(wavenum)
est store amtest 

hausman fixeff amtest 
 

end